Как добавить элементы одного одномерного массива в другой (того же типа) БЕЗ цикла и быстрее, чем с циклом

Option Base 1
Option Explicit
Option Private Module
'==================================================================================================
Sub PRDX_Arr1D_AddData_Str(aMain() As String, aAdd() As String)
Dim nA&, nM&, LBa&, UBa&, n&
 
    LBa = LBound(aAdd)
    UBa = UBound(aAdd)
    nA = UBa - LBa + 1
    nM = UBound(aMain)
    ReDim Preserve aMain(LBound(aMain) To nM + nA)
 
    For n = LBa To UBa
        nM = nM + 1: aMain(nM) = aAdd(n)
    Next n
End Sub
'==================================================================================================
Sub PRDX_Arr1D_Merge_Str(aOut() As String, ParamArray aArrStr())
Dim x, y, t!, n&, nEl&
 
    For Each x In aArrStr   ' 35% of TotalTime
        nEl = nEl + (UBound(x) - LBound(x) + 1)
    Next x
 
    ReDim aOut(nEl)
    
    For Each x In aArrStr   ' 65% of TotalTime
        For Each y In x
            n = n + 1: aOut(n) = y
        Next y
    Next x
 
End Sub
'==================================================================================================
Sub PRDX_Arr1D_Merge_Str_ByAdd(aOut() As String, ParamArray aArrStr())
Dim a$(), n&
 
    n = LBound(aArrStr)
    aOut = aArrStr(n)
    
    For n = n + 1 To UBound(aArrStr)
        a = aArrStr(n)
        PRDX_Arr1D_AddData_Str aOut, a
    Next n
End Sub
'--------------------------------------------------------------------------------------------------
Private Sub Test_Arr1D_AddOrMerge()
Dim a$(), a1$(), a2$(), t!, n&
Const nEl& = 1000000 ' 1 mln
 
    t = Timer
        ReDim a1(nEl)
        
        For n = 1 To nEl
            a1(n) = "TestStringWithLong_" & n
        Next n
    Debug.Print Round(Timer - t, 2), "Fill"     ' 0.2
    
    t = Timer
        a2 = a1
    Debug.Print Round(Timer - t, 2), "Copy"     ' 0.1
 
    t = Timer
        PRDX_Arr1D_Merge_Str a, a1, a2
    Debug.Print Round(Timer - t, 2), "Merge"    ' 0.9
    Erase a
 
    t = Timer
        PRDX_Arr1D_Merge_Str_ByAdd a, a1, a2
    Debug.Print Round(Timer - t, 2), "Merge2"   ' 0.3
 
     t = Timer
        PRDX_Arr1D_AddData_Str a1, a2
    Debug.Print Round(Timer - t, 2), "Add"      ' 0.1
End Sub

Private Declare PtrSafe Sub ZeroMemory Lib "kernel32.dll" Alias "RtlZeroMemory" (ByRef Destination As Any, ByVal Length As LongPtr)
#If Win64 Then
    Private Const ptrSz^ = 8
#Else
    Private Const ptrSz& = 4
#End If
Private Enum MergeType
    mrgCopy
    mrgMove
End Enum
 
Private Sub ExapleMergeStrArr1D()
    Dim arMain$(), arEmp$()
    ReDim arSrc$(2)
    
    arSrc = Split("Строка1 Строка2 Строка3", " ")
    MergeStrArr1D arMain, arSrc          'копирование строк из arSrc в arMain
    
    arSrc = Split("Строка4 Строка5 Строка6 Строка7", " ")
    MergeStrArr1D arMain, arSrc, mrgMove 'перемещение строк из arSrc в arMain    
End Sub
 
Private Sub MergeStrArr1D(arDst$(), arSrc$(), Optional ByVal mrgTp As MergeType)
'(Копирование/перемещение строк из одного строкового массива в другой (объединение массивов)
'Testuser 31.05.24 'https://www.cyberforum.ru/vba/thread3169815.html#post17322611
    Dim UbDst&, LbSrc&, UbSrc&, CntSrc&, SzSrc&, arCpy$()
    
    UbDst = -1
    On Error Resume Next 'если массив arDst не инициализирован, произойдет ошибка, но она не мешает дальнейшему процессу
      UbDst = UBound(arDst)
    On Error GoTo 0
    LbSrc = LBound(arSrc): UbSrc = UBound(arSrc)
    CntSrc = UbSrc - LbSrc + 1
    SzSrc = CntSrc * ptrSz
    ReDim Preserve arDst(UbDst + CntSrc)
    
    If mrgTp = mrgCopy Then
        arCpy = arSrc                     'создаем копию массива-источника
        CopyMemory ByVal VarPtr(arDst(UbDst + 1)), ByVal VarPtr(arCpy(LbSrc)), SzSrc 'копируем указатели
        ZeroMemory ByVal VarPtr(arCpy(LbSrc)), SzSrc 'обнуляем указатели в источнике
    Else
        CopyMemory ByVal VarPtr(arDst(UbDst + 1)), ByVal VarPtr(arSrc(LbSrc)), SzSrc
        ZeroMemory ByVal VarPtr(arSrc(LbSrc)), SzSrc
    End If
End Sub

' Based on: Testuser 31.05.24 'https://www.cyberforum.ru/vba/thread3169815.html#post17322611
Sub PRDX_Arr1D_Add_Str_API(aMain$(), aAdd$(), Optional SaveAdd As Boolean)
Dim LBm&, UBm&, LBa&, UBa&, nA&, SzAdd^, aBuf$()
Const ptrSz^ = 8 ' — For Win64 Else 4
 
    LBm = LBound(aMain): UBm = UBound(aMain)
    LBa = LBound(aAdd):  UBa = UBound(aAdd)
    nA = UBa - LBa + 1:  SzAdd = nA * ptrSz
    ReDim Preserve aMain(LBm To UBm + nA)
 
    If SaveAdd Then
        aBuf = aAdd
        API_Memory_Copy ByVal VarPtr(aMain(UBm + 1)), ByVal VarPtr(aBuf(LBa)), SzAdd
        API_Memory_Zero ByVal VarPtr(aBuf(LBa)), SzAdd
    Else
        API_Memory_Copy ByVal VarPtr(aMain(UBm + 1)), ByVal VarPtr(aAdd(LBa)), SzAdd
        API_Memory_Zero ByVal VarPtr(aAdd(LBa)), SzAdd: Erase aAdd
    End If
End Sub
'==================================================================================================
Private Sub Test_PRDX_Arr1D_Add_Str_API()
Dim a$(), a2$(), s$, t!, n&
Const nEl& = 10000000 ' 10 mln
Const nType& = 3
 
    t = Timer
        ReDim a(nEl), a2(nEl)
 
        For n = 1 To nEl
            a(n) = "TestStringWithLong_" & n
            a2(n) = "TestStringWithLong_" & (n + nEl)
        Next n
    Debug.Print Round(Timer - t, 2), "Fill"                         ' 1.81
 
'    t = Timer
'        a2 = a
'    Debug.Print Round(Timer - t, 2), "Dupl"                        ' 0.83
 
    t = Timer
        Select Case nType
            Case 1: PRDX_Arr1D_Add_Str a, a2:            s = "Add"  ' 0.98
            Case 2: PRDX_Arr1D_Add_Str_API a, a2, True:  s = "Copy" ' 0.86
            Case 3: PRDX_Arr1D_Add_Str_API a, a2, False: s = "Move" ' 0.04 (!!!) WOW
        End Select
    Debug.Print Round(Timer - t, 2), s, LBound(a), UBound(a)
    Debug.Print a(LBound(a)), a(UBound(a)) ', "«" & a2(LBound(a2)) & "»", "«" & a2(UBound(a2)) & "»" ' TestStringWithLong_1 | TestStringWithLong_20 000 000 | «» | «»
 
End Sub

Option Base 1
Option Explicit
Option Private Module
'==================================================================================================
' String
'==================================================================================================
' Based on: Testuser 31.05.24 'https://www.cyberforum.ru/vba/thread3169815.html#post17322611
Sub PRDX_Arr1D_Add_Str_API(aMain$(), aAdd$(), Optional SaveAdd As Boolean)
Dim LBm&, UBm&, LBa&, UBa&, nA&, SzAdd^, aBuf$()
Const ptrSz^ = 8 ' — For Win64 Else 4
 
    LBa = LBound(aAdd):  UBa = UBound(aAdd)
    nA = UBa - LBa + 1:  SzAdd = nA * ptrSz
 
    If PRDX_Arr_Check_IsFull(aMain) Then    ' ArrAdd
        UBm = UBound(aMain)
        ReDim Preserve aMain(LBound(aMain) To UBm + nA)
    Else                                    ' ArrReplace
        UBm = LBa - 1                       ' Fake UBound
        ReDim aMain(LBa To UBa)             ' Size by aAdd
    End If
 
    If SaveAdd Then
        aBuf = aAdd
        API_Memory_Copy ByVal VarPtr(aMain(UBm + 1)), ByVal VarPtr(aBuf(LBa)), SzAdd
        API_Memory_Zero ByVal VarPtr(aBuf(LBa)), SzAdd
    Else
        API_Memory_Copy ByVal VarPtr(aMain(UBm + 1)), ByVal VarPtr(aAdd(LBa)), SzAdd
        API_Memory_Zero ByVal VarPtr(aAdd(LBa)), SzAdd: Erase aAdd
    End If
End Sub