Полезные BAT/CMD скрипты

@Echo Off
ChCp 1251>Nul
If "%~1"=="" (
    Echo The correct syntax:
    Echo %~nx0 "Full\path\to\Folder 1" ["Full\path\to\Folder 2"] ...
    Pause>Nul
    Exit
)
For /F "Tokens=1 Delims=." %%i In ('WMIC OS Get LocalDateTime^|Find "."') Do Set t=%%i
Set zDT=_Zero_%t:~2,2%%t:~4,2%%t:~6,2%_%t:~8,2%-%t:~10,2%
Set f=%~1& Set cnt=2& Set c=0& Set cf=0
:_loop
    If "%f:~0,1%"=="\" Set /A cnt+=1
    Set f=%f:~1%
If Defined f GoTo _loop
Set /A cntI=cnt-1
 
If "%~2"=="" (
    If Exist "%~1\*" Call :_makeDir "%~1%zDT%"
    Call :_item "%~1" "%~1%zDT%" "%~1" "%cnt%" "%~1%zDT%" "%~dpn1%zDT%%~x1"
    If Exist "%~1\*" For /R "%~1%zDT%" %%f In (.) Do Set /A cf+=1
) Else (
    Call :_makeDir "%~dp1%zDT%"
    For %%i In (%*) Do Call :_item "%%~i" "%~dp1%zDT%\%%~nxi" "%~dp1%%~nxi" "%cntI%" "%~dp1%zDT%" "%~dp1%zDT%\%%~nxi"
    For /R "%~dp1%zDT%" %%f In (.) Do Set /A cf+=1
)
Echo Complete!
Echo Folders=%cf%   Files=%c%
Echo.
Pause
Exit
 
:_item
If Exist "%~1\*" (
    xCopy /T /E /H /K "%~1" "%~2\"|| GoTo :_err
    PushD "%~3"
    For /F "tokens=%~4* delims=\" %%a In ('Dir /S /B /A:-D') Do (
        If "%%~b"=="" (CD.>"%~5\%%~a") Else CD.>"%~5\%%~a\%%~b"
        Set /A c+=1
    )
    PopD
) Else (
    CD.>"%~6"
    Set /A c+=1
)
GoTo :EOF
 
:_err
For /R "%~2" %%f In (.) Do Set erf=%%f
Set erf=%erf:~0,-2%
Call Set erf=%%erf:%~2=%~1%%
RD /S /Q "%~5"
Echo Error xCopy on file:
Echo %erf%
Pause>Nul
Exit
 
:_makeDir
If Exist "%~1" RD /S /Q "%~1"
MD "%~1"
GoTo :EOF

@echo off
SetLocal
mode con: cols=60 lines=10
Color 9A
 
Set Text=Maded by Dragokas
Set Color=1A
::left, right, center
Set Alignment=right
 
Call :ColorText "%text%" "%color%" "%Alignment%"
Call :ColorText "Working with Colors" "1d" "center"
Echo Press any key...
pause>nul
goto :eof
 
:ColorText %1-in.Text %2-in.Color.HEX %3-Alignment
  Call :SetTextPosition "%~1" "%~3"
  md "%temp%\_bin2" 2>nul
  pushd "%temp%\_bin2"
  echo.>"%~1"
  findstr /V /a:%~2 "1" "*"
  popd
  rd /s /q "%temp%\_bin2"
  Exit /B
 
:SetTextPosition %1-in.Text %2-in.Alignment
  if /i "%~2" neq "left" (
    call :GetConsoleWidth _ConWidth
    call :var_count "%~1" _len
    SetLocal EnableDelayedExpansion
    if /i "%~2"=="right" (
      Set /A _ind=!_ConWidth!-!_len!-1
      Call :indent !_ind!
    )
    if /i "%~2"=="center" (
      Set /A _ind=^(!_ConWidth!-!_len!^)/2
      Call :indent !_ind!
    )
    EndLocal
  )
  Exit /B
 
:GetConsoleWidth %1-out.ConsoleWidth
  For /F "skip=4 tokens=2" %%w In ('mode con') Do Set %~1=%%w& Exit /B
 
:var_count %1-in.Text %2.out.Len.of.Text
  set _var=%~1& set _count=0
  :count--
  set _var=%_var:~1%
  set /a _count+=1
  if not defined _var (set %~2=%_count%& exit /b) else (goto :count--)
 
:indent %1-in.Count.of.Spaces
  SetLocal EnableDelayedExpansion
  ::Здесь нужно заменить символ ниже на BackSpace (код 0x08) <<<<<---------
  Set _BS=
  Set _Spaces=
  for /L %%C in (1,1,%~1) do Set "_Spaces=!_Spaces! "
  <nul set /p "_Spaces=_%_BS%%_Spaces%"
  EndLocal& Exit /B

@echo off&:: by Alex Dragokas
Setlocal EnableDelayedExpansion EnableExtensions
Echo.
::Получаем PNPDeviceID и PhysicalDrive Name устройств, подключенных по интерфейсу USB
echo Перечень cъемных накопителей:
echo.
For /F "Skip=2 Tokens=2-4 delims=," %%i In (
  'WMIC DiskDrive Where InterfaceType^="USB" Get Name^,PNPDeviceID^,Model /Value /format:csv 2^>nul'
) do (
    Set AtLeastOneDevice=true
    Call :Get_USB_SN "%%k" Device_SN
    Call :GetPartition "%%j" Drives
    Echo Model: %%i
    Echo %%j
    Echo Disk^(s^):     !Drives!
    Echo Device S/N:         "!Device_SN!"
    Echo.
)
if not defined AtLeastOneDevice Echo Съемных USB накопителей не обнаружено.
Echo.
Echo Перечень жестких дисков:
Echo.
For /F "Skip=2 Tokens=2-4 delims=," %%i In (
  'WMIC DiskDrive Where "InterfaceType^!^='USB'" Get Name^,PNPDeviceID^,Model /Value /format:csv'
) do (
    Call :GetPartition "%%j" Drives
    Call :Get_HDD_SN "%%j" Device_SN
    Echo Model: %%i
    Echo %%j
    Echo Disk^(s^):     !Drives!
    Echo Device S/N:         "!Device_SN!"
    Echo "!Device_SN!">>%~dp0file.txt
    Echo.
)
pause>nul
Goto :eof
 
::Парсим часть с серийным номером устройства
:Get_USB_SN %1-in.PNPDeviceID %2-out.Device_S/N
  Set "%~2="
  Set "PNP=%~1"
  Set "PNP=%PNP:\=" "%"
  Set "PNP=%PNP:;=" "%"
  Set "PNP=%PNP:&=" "%"
  Set _Prev=
  For %%i in ("%PNP%") do (
    if "!_Prev:~0,4!"=="REV_" (Set "%~2=%%~i"& Exit /B)
    Set "_Prev=%%~i"
  )
  Exit /B
 
:Get_HDD_SN %1.in-PhysicalDrive_Name %2-out.Device_S/N
  Set "tag=%~1"
  Set "tag=%tag:\=\\%"
  For /F "UseBackQ skip=2 tokens=2 delims=," %%i In (
    `wmic path Win32_PhysicalMedia where "tag='%tag%'" Get SerialNumber /format:csv`
  ) do call set "_serial=%%i"
  ::Выше используется Call, чтобы удалить служебный символ 0x0D из переменной
  set "_serial=%_serial: =%"
  ::Проверяем признак 16-ричного кода (ответ длинной 40 символов)
  if "%_serial:~39,1%" neq "" Call :Hex_To_String "%_serial%" "_serial"
  set "%~2=%_serial%"
  Exit /B
 
:Hex_To_String %1-in.Reversed.Hex.Number %2-out.String
  SetLocal& set "x16=%~1"
  set n=45
  for %%A in (- . / 0 1 2 3 4 5 6 7 8 9) do set s.!n!=%%A& set /a n+=1
  set n=65
  for %%A in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set s.!n!=%%A& set /a n+=1
  set n=97
  for %%A in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set s.!n!=%%A& set /a n+=1
  set xs=
  for /L %%C in (0,4,8184) do (
    if "!x16:~%%C,1!"=="" goto _ex_Hex
    set /A cplus=%%C+2
    call set /A x10=0x%%x16:~!cplus!,2%%
    call set xs=!xs!%%s.!x10!%%
    set /A x10=0x!x16:~%%C,2!
    call set xs=!xs!%%s.!x10!%%
  )
  :_ex_Hex
  EndLocal& set "%~2=%xs%"& Exit /B
 
::Конвертация PhysicalDrive Name -> Partition Names -> Drive Names
  :GetPartition %1.in-PhysicalDrive_Name %2-out.Drive_Names
  Set "%~2="
  For /F "skip=2 delims==, tokens=3,6-7" %%i In (
    'WMIC path Win32_DiskDriveToDiskPartition get /format:csv'
  ) do (
    if %%i=="%~1" (
      For /F "skip=2 delims==, tokens=3-4,7" %%I In (
        'WMIC path Win32_LogicalDiskToPartition get Antecedent^,Dependent /format:csv'
      ) do (
        if "%%I,%%J"=="%%j,%%k" Set "%~2=!%~2! %%K"
  )))
  Exit /B

@Echo Off
 
:: Максимальное значение обрабатываемого числа для арифметики в CMD = 2^30 - 1 (2147483647 = 2048 Mb. )
 
:: В версии 3:
:: добавлена возможность считать файлы более 2 Гб.
:: выполняется проверка на отсев дисков не имеющих ФС (не ругается на вставленные флешки)
 
:: в версии 4:
:: добавлена функция очистки DNS (исключает проблемы с сетевым подключением)
:: добавлена функция очистки не запускаемых приложений в окне msconfig с огранчением по дате - до 10 дней включительно.
:: исправлена ошибка удаления временных файлов Opera "%DirProg%" на "!DirProg!"
:: Добавлен браузер Google Chrome
:: Добавлено удаление остатков браузеров,ранее установленных и в дальнейшем удалённых из системы - RD /S/Q
:: Проверка наличия браузеров сделана по исполняемому файлу *.exe
:: Добавлена возможность исключить из расчёта размера директории Temp некоторые файлы и папку.
:: Добавлено удаление и расчет размера истории открытых файлов.
:: Добавлено вывод сообщения в случае запуска скрипта при открытии Word.
:: Для УО добавлена очистка рабочего стола от временных файлов Консультанта ПЛЮС.(без расчёта размера)
 
:: в версии 5:
:: Добавлен расчёт и удаление файлов истории, имеющх в начале имени спецсимвол "!"
:: Исключено из расчёта размера директории временных файлов Internet Explorer файла index.dat. 
:: Добавлен расчёт и очистка истории Java, Flash Player
:: Добавлена строчка "Очистка истории открываемых файлов"
 
:: в версии 6:
:: добавлена поддержка очистки корзин в Windows 7
 
:: в версии 7:
:: добавлена очистка файлов *.log, *.old, *.bak, *.temp, *.tmp, *.---, *._mp, *.syd
:: добавлена очистка скаченных файлов из "%windir%\SoftwareDistribution\Download\*"
:: Добавлена очистка истории в Google :Visited Links,Archived History
:: Изменен подсчёт корзин. Теперь считает и из-под пользователя.
:: поддержка Windows XP Home
:: поддержка антивирусной программы ESET Smart Security
:: Мелкие исправления
 
  SetLocal enabledelayedexpansion
color 1a
title sov44
mode con: cols=58 lines=22
  echo.
  echo   -----------------------------------------------------
  echo               УДАЛЕНИЕ ВРЕМЕННЫХ ФАЙЛОВ        
  echo   -----------------------------------------------------
  echo.
  echo.
Set Cnt=0
 
rem 1. Удаление временных файлов Windows
 
:: поиск и удаление временных файлов по расширению на диске С
set iSumL=0
::set Rash=*.log;*.old;*.bak;*.temp;*.tmp;*.---;*._mp;*.syd;
set Rash=*.log;*.temp;*.tmp;
 
  For /F "Delims=" %%I In ('Dir c:\%Rash% /B/S/A:-D-H 2^>nul') Do (
      2>&1 del /q "%%I" | 1>nul findstr "."
      if errorlevel 1 (set /a iSumL +=%%~zI)
)
Set /A Cnt +=!iSumL!
 
:: очистка директории Temp
Set DirProg=%WinDir%\TEMP
 
:: Исключаем из расчёта временные папки и файлы, которые создают работающие приложения
 
:: Для проверки установленной витруальной машины VM Ware
if exist "%WinDir%\TEMP\Perflib_Perfdata_*.dat" set "File1=Perflib_Perfdata_78c.dat"
if exist "%WinDir%\TEMP\vmware-SYSTEM" set "Dir1=vmware-SYSTEM"
 
:: Для KAV 2011
if exist "%ProgramFiles%\Kaspersky Lab" (set "File1=kls????.tmp"& set "File2=Perflib_Perfdata_???.dat")
 
:: для NOD 5 Smart Security
if exist "%ProgramFiles%\ESET\ESET Smart Security\egui.exe" (set "File1=fb_????.evn"& set "File2=Perflib_Perfdata_??*.dat"& set "File3=fb_????.lck")
 
Call :_DirSize "%DirProg%"
Set /A AllSize +=dirsize
Call :_DirSize "%DirProg%\%Dir1%"
Set /A AllSize -=dirsize
For %%i In ("%DirProg%\%File1%" "%DirProg%\%File2%" "%DirProg%\%File3%") Do If Exist %%i Set /A AllSize -= %%~zi
if "%AllSize:~0,1%"=="-" set AllSize=0
 
Set /A Cnt +=%AllSize%
 
  PUSHD "%DirProg%"
  2>Nul RD /S/Q "%DirProg%"
  POPD
echo    Очистка временных файлов Windows              - OK
goto :cl_2
 
:_DirSize
Set dirsize=0
For /F "skip=4 tokens=1-3" %%a IN ('Dir "%~1" /-C /S /A:-D /A:-H  2^>nul') Do (
    If !flag!==1 Set dirsize=%%c
    If "%%b"=="файлов:" (Set flag=1) Else (Set flag=0)
)
GoTo :EOF
rem ------------------------------------------------------------------------
 
:cl_2
rem 2. Очистка истории Windows
 
::Очистка истории реестра  **НЕ ПРОВЕРЕНА БЕЗОПАСНОСТЬ!!!**
:: меню "ПУСК
::Reg Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\RunMRU" /f 1>Nul 2>&1
::Reg Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\ComDlg32\OpenSaveMRU" /f 1>Nul 2>&1
::Reg Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\RecentDocs" /f 1>Nul 2>&1
::кэш уведомлений панели задач
::Reg Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\TrayNotifi" /f 1>Nul 2>&1
 
 
:: Пути и расширения удаляемых файлов
if exist "%WinDir%\system32\systeminfo.exe" (
  >"%temp%\MsgBox.vbs" echo WScript.Quit^(MsgBox^(WScript.Arguments^(1^) ^& vbCrLf ^& WScript.Arguments^(2^) ^& vbCrLf ^& vbCrLf ^& WScript.Arguments^(3^), vbYesNo+vbDefaultButton1,WScript.Arguments^(0^)^)^)
    tasklist 2>nul|find /i "winword.exe" 1>nul && (WScript "%temp%\MsgBox.vbs" "Внимание^!" " Для успешной работы скрипта закройте открытые документы Word" "     После нажатия на кнопку они будут закрыты принудительно" "                                             Продолжить?"^
    & taskkill /F /IM winword.exe 1>nul 2>nul &>nul ping 127.0.0.1 -n 1 &goto :cl_2)
    del /q "%temp%\MsgBox.vbs" 2>nul
)
set iSumT=0
set "dr=%USERPROFILE%\Recent"& call :Calc "%dr%" *.lnk
set "dr=%USERPROFILE%\Application Data\Microsoft\Office\Последние файлы"& call :Calc "%dr%" *.lnk
set "dr=%USERPROFILE%\Local Settings\Temporary Internet Files\Content.MSO"& call :Calc "%dr%" *.*
set "dr=%USERPROFILE%\Local Settings\Temporary Internet Files\Content.Word"& call :Calc "%dr%" *.*
 
Set /A Cnt +=%iSumT%
 
del /q "%USERPROFILE%\Рабочий стол\CONS_LOG.TXT" 1>Nul 2>&1
RD /S/Q "%USERPROFILE%\Рабочий стол\CONS.CFG" 1>Nul 2>&1
 
Set "DirProgJ=%USERPROFILE%\Application Data\Sun\Java\Deployment\cache\6.0"& call :Calc1 "%DirProgJ%"
Set "DirProgJ=%USERPROFILE%\Application Data\Macromedia\Flash Player"& call :Calc1 "%DirProgJ%"
set "DirProgJ=%windir%\SoftwareDistribution\Download"& call :Calc1 "%DirProgJ%"
 
echo    Очистка истории открываемых файлов            - OK
goto :cl_3
 
:Calc
for /f "delims=" %%i in ('dir /b/a-d "%dr%\%2" 2^>nul') do (
         set /a iSumT +=%%~zi 1>Nul 2>&1
setlocal disabledelayedexpansion
         del /f/q "%dr%\%%i" 1>Nul 2>&1
endlocal
)
GoTo :EOF
 
:Calc1
For /F "skip=4 tokens=1-3" %%a IN ('Dir "%DirProgJ%" /-C /S 2^>nul') Do (
    If !flag!==1 Set dirsizeJ=%%c
    If "%%b"=="файлов:" (Set flag=1) Else (Set flag=0)
      )
Set /A Cnt +=dirsizeJ
PUSHD "%DirProgJ%" 2>nul
2>Nul RD /S/Q "%DirProgJ%"
POPD
GoTo :EOF
 
rem -------------------------------------------------------------------------
pause
:cl_3
rem 3. Очистка временных файлов Opera
 
if exist "%programfiles%\Opera\opera.exe" (
Set DirProg=%USERPROFILE%\Local Settings\Application Data\Opera\opera\cache
 
For /F "skip=4 tokens=1-3" %%a IN ("'Dir "!DirProg!" /-C /S ' 2^>nul") Do (
    If !flag!==1 Set dirsize1=%%c
    If "%%b"=="файлов:" (Set flag=1) Else (Set flag=0)
      )
Set /A Cnt +=dirsize1
PUSHD "!DirProg!" 2>nul
2>Nul RD /S/Q "!DirProg!"
POPD
echo    Очистка временных файлов Opera                - OK
 ) Else ( 
RD /S/Q "%USERPROFILE%\Local Settings\Application Data\Opera" 1>Nul 2>&1
RD /S/Q "%USERPROFILE%\Application Data\Opera" 1>Nul 2>&1
RD /S/Q "%ProgramFiles%\Opera" 1>Nul 2>&1
echo    Очистка временных файлов Opera                - --  )
 
rem ------------------------------------------------------------------------
 
::cl_4
rem 4. Очистка истории в Опере
 
if not exist "%programfiles%\Opera\opera.exe" echo    Очистка истории в Opera                       - -- ^ & goto :cl_5
 set /a iSumO =0
call :CalcAndDel "%AppData%\Opera\Opera\typed_history.xml"
call :CalcAndDel "%AppData%\Opera\Opera\global_history.dat"
call :CalcAndDel "%AppData%\Opera\Opera\search_field_history.dat"
call :CalcAndDel "%AppData%\Opera\Opera\download.dat"
Set /A Cnt +=%iSumO%
echo    Очистка истории в Opera                       - OK
goto :cl_5
 
:CalcAndDel
    set sFile=%~1
        if defined sFile (
        if exist "%sFile%" (
            set /a iSumO += %~z1
            del /f /q "%sFile%"
        )
    )   
GoTo :EOF
 
rem ------------------------------------------------------------------------
 
:cl_5
:::: rem 5. Очистка временных файлов Internet Explorer
:::: rem Исключаем из расчёта файл index.dat
:: 
::set "File1=index.dat"
::Set DirProg=%USERPROFILE%\Local Settings\Temporary Internet Files\Content.IE5
::
::Call :_DirSizeE "%DirProg%"
::Set /A AllSize +=dirsize2
::For %%i In ("%DirProg%\%File1%" ) Do If Exist %%i Set /A AllSize -= %%~zi
::Set /A Cnt +=%AllSize%
::
::PUSHD "%DirProg%"
::2>Nul RD /S/Q "%DirProg%"
::POPD
::echo    Очистка временных файлов Internet Explorer    - OK
::
::rem ------------------------------------------------------------------------
::
::rem 5. Очистка истории в Internet Explorer
::RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 1  :: Очистить Журнал 
::RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 2  :: Очистить файлы "cookie" 
::RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 16 :: Очистить данные веб-форм 
:::: RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 32  :: Очистить пароли
::
::echo    очистка истории в Internet Explorer           - OK
::
::goto :cl_6
::
:::_DirSizeE
::Set dirsize2=0
::For /F "skip=4 tokens=1-3" %%a IN ('Dir "%~1" /-C /S /A:-D 2^>nul') Do (
::  If !flag!==1 Set dirsize2=%%c
::  If "%%b"=="файлов:" (Set flag=1) Else (Set flag=0)
::)
::exit /b
 
rem ------------------------------------------------------------------------
 
:cl_6
rem 6. Очистка временных файлов Mozilla Firefox
 
if exist "%programfiles%\Mozilla Firefox\firefox.exe" (
 
for /f "usebackq tokens=2 delims==" %%i in (`type "%APPDATA%\Mozilla\Firefox\profiles.ini"^|find.exe "Path="`) do ^
set MF_temp=%USERPROFILE%\Local Settings\Application Data\Mozilla\Firefox\%%i\Cache
 
For /F "skip=4 tokens=1-3" %%a IN ('Dir "!MF_temp!" /-C /S ') Do (
    If !flag!==1 Set dirsize3=%%c
    If "%%b"=="файлов:" (Set flag=1) Else (Set flag=0)
    )
Set /A Cnt +=dirsize3
PUSHD "!MF_temp!"
2>Nul RD /S/Q "!MF_temp!"
POPD
echo    Очистка временных файлов Mozilla Firefox      - OK
       ) Else (
RD /S/Q "%USERPROFILE%\Local Settings\Application Data\Mozilla" 1>Nul 2>&1
RD /S/Q "%USERPROFILE%\Application Data\Mozilla" 1>Nul 2>&1
RD /S/Q "%ProgramFiles%\Mozilla Firefox" 1>Nul 2>&1
 
echo    Очистка временных файлов Mozilla Firefox      - --  )
 
rem ------------------------------------------------------------------------
 
:cl_7
rem 7. Очистка истории в Mazilla Firefox
 
if not exist "%programfiles%\Mozilla Firefox\firefox.exe" echo    Очистка истории в Mazilla Firefox             - -- ^ & goto cl_8 
 
for /f "usebackq tokens=2 delims==" %%i in (`type "%APPDATA%\Mozilla\Firefox\profiles.ini"^|find.exe "Path="`) do ^
set MF_his=%AppData%\Mozilla\Firefox\%%i
set /a iSum = 0
::call :CalcAndDel "%MF_his%\places.sqlite"
call :CalcAndDel "%MF_his%\webappsstore.sqlite"
call :CalcAndDel "%MF_his%\formhistory.sqlite"
 
Set /A Cnt +=%iSumM%
echo    Очистка истории в Mazilla Firefox             - OK
goto :cl_8
 
:CalcAndDel
    set sFile=%~1
    
    if defined sFile (
        if exist "%sFile%" (
            set /a iSumM += %~z1
            del /f /q "%sFile%"
        )
    )   
GoTo :EOF
 
rem ------------------------------------------------------------------------
 
:cl_8
rem 8. Очистка временных файлов Google Chrome
 
if exist "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\Application\chrome.exe" (
Set DirProgCr1=%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Cache
 
For /F "skip=4 tokens=1-3" %%a IN ('Dir "!DirProgCr1!" /-C /S ') Do (
    If !flag!==1 Set dirsize4=%%c
    If "%%b"=="файлов:" (Set flag=1) Else (Set flag=0)
      )
Set /A Cnt +=dirsize4
PUSHD "!DirProgCr1!"
2>Nul RD /S/Q "!DirProgCr1!"
POPD
echo    Очистка временных файлов Google Chrome        - OK
 ) Else (
 RD /S/Q "%USERPROFILE%\Local Settings\Application Data\Google" 1>Nul 2>&1
 RD /S/Q "%USERPROFILE%\Мои документы\Downloads" 1>Nul 2>&1
 echo    Очистка временных файлов Google Chrome        - --  )
 
rem ------------------------------------------------------------------------
 
:cl_9
rem 9. Очистка истории в Google Chrome
if not exist "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\Application\chrome.exe" echo    Очистка истории в Google Chrome               - -- ^ & goto :cl_10
 set /a iSumG =0
call :CalcAndDel_2 "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Current Session"
call :CalcAndDel_2 "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\History"
call :CalcAndDel_2 "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\History Index *-*"
call :CalcAndDel_2 "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Last Session"
call :CalcAndDel_2 "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Visited Links"
call :CalcAndDel_2 "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Archived History"
 
Set /A Cnt +=%iSumG%
echo    Очистка истории в Google Chrome               - OK
goto :cl_10
 
:CalcAndDel_2
    set sFile=%~1
    
    if defined sFile (
        if exist "%sFile%" (
            set /a iSumG += %~z1
            del /f /q "%sFile%"
        )
    )   
    GoTo :EOF
 
rem ------------------------------------------------------------------------
 
:cl_10
rem 10. Очистка кэш распознавателя DNS (исключает проблемы с сетевым подключением)
rem Удаление не запускаемых приложений в окне msconfig с проверкой их наличия
rem блок скрипта настроен на работу до 10 числа каждого месяца
 
ipconfig /flushdns 1>Nul 2>&1
 
set "tmr=%date:~0,2%"
If %tmr% LEQ 10 (
call :fn1 "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg"
call :fn1 "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder" 
goto :cl_11
 
:fn1
for /f "skip=4 delims=" %%a in ('reg query %1 2^>nul' ) do reg delete "%%a" /f 1>Nul 2>&1
GoTo :EOF
)
rem -------------------------------------------------------------------------------
 
:cl_11
rem 11. Очистка корзины на всех дисках,подсчёт размера удаляемых файлов.
set dirsize5 =0
if exist "C:\RECYCLER" (Set "DirProg=RECYCLER") else (Set "DirProg=^$Recycle.Bin")
 
FOR %%f IN (Z Y X W U V T S R Q P O N M L K J I H G F E D C) DO (
Set "flag=0"
For /F "Skip=4 Tokens=1-3" %%a In ('DIR/-C/S/A:-D "%%f:\%DirProg%" 2^>Nul') Do (
      If !flag!==1 Set /a dirsize5 +=%%c
      If "%%b"=="файлов:" (Set flag=1) Else (Set flag=0)
))
Call:SUM !Cnt! !dirsize5! Cnt
 
Set rst=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches
REG Add "%rst%\Recycle Bin" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG Delete "%rst%\Compress old files" /f 2>nul
Cleanmgr /sagerun:1
echo    Очистка корзины на всех дисках                - OK
rem ------------------------------------------------------------------------
 
Call:UDIV2 %Cnt% dirsizeMB  20
Call:UMUL2 %dirsizeMB% CntT 20
Call:SUM %Cnt% -%CntT% ost
 
Set/a $.mb=(%ost%*100)/(1024*1024)
Set "$.mb=0%$.mb%"& Set "$.mb=!$.mb:~-2!"
 
echo/
echo/
echo        Очистка выполнена, всего удалено %dirsizeMB%,%$.mb% Мб
 
ping 127.0.0.1 -n 8 >nul
 
exit
 
:SUM  %uint%  %uint%  %VarRes%
::----------------------------
SETLOCAL EnableDelayedExpansion
(set "$a=%~1"& set "$b=%~2"
 if "!$a:~,1!"=="-" (set "$az=-"&set "$a=!$a:-=!") else set "$az="
 if "!$b:~,1!"=="-" (set "$bz=-"&set "$b=!$b:-=!") else set "$bz="
 for /f "tokens=* delims=0" %%i in ("!$a:~-9!") do set/a "$al=%%i+0"&set/a "$ah=!$a:~,-9!+0"
 for /f "tokens=* delims=0" %%i in ("!$b:~-9!") do set/a "$bl=%%i+0"&set/a "$bh=!$b:~,-9!+0"
 
 set/a "$sl=(!$az!!$al!)+(!$bz!!$bl!)"&set/a $p=!$sl:~,-9!+0&set/a "$sl=!$sl!-(!$p!000000000)"
 set/a "$sh=(!$az!!$ah!)+(!$bz!!$bh!)+(!$p!+0)"
 if !$sh! gtr 0 if !$sl! lss 0 set/a $sh-=1& set/a "$sl=(1000000000+!$sl!)"
 if !$sh! lss 0 if !$sl! gtr 0 set/a $sh+=1& set/a "$sl=(!$sl!-1000000000)"
 for /f "delims=0123456789" %%i in ("!$sh!!$sl!") do set "$z=%%i"
 if !$sh! equ 0 if !$sl! equ 0 set "$z=0"
 set "$sl=00000000!$sl:-=!"
)
 for /f "tokens=* delims=0" %%i in ("!$sh:-=!!$sl:~-9!") do ENDLOCAL& set "%~3=%$z%%%i"
GoTo:EOF
 
:UDIV2  %uint% %VarRes% %uint%
::----------------------------
 SETLOCAL EnableDelayedExpansion
(set "$a=%~1"& set/a "$c=%~3+0"& if !$c! equ 0 set "$c=1"
 for /f "tokens=* delims=0" %%i in ("!$a:~-9!") do set/a "$al=%%i+0,$ah=!$a:~,-9!+0"
 for /l %%i in (1,1,!$c!) do (
   set/a "$p=$ah&1,$ah>>=1,$al>>=1"
   if !$p!==1 set/a $al=$al+500000000)
 set "$z="& if !$ah! equ 0 if !$al! equ 0 set "$z=0"
)
 for /f "tokens=* delims=0" %%i in ("!$ah!!$al!") do ENDLOCAL& set "%~2=%$z%%%i"
GoTo:EOF
 
:UMUL2  %uint% %VarRes% %uint%
::----------------------------
(SETLOCAL EnableDelayedExpansion
 set %~2=%~1& set/a "$c=%~3+0"& if !$c! equ 0 set "$c=1"
 for /l %%i in (1,1,!$c!) do Call:SUM !%~2! !%~2! %~2
 for /f %%i in ("!%~2!") do ENDLOCAL& set "%~2=%%i"
)
GoTo:EOF
 
rem Скрипт создан благодаря помощи Iska, gora, amel27  _http://forum.oszone.net/forum-102.html

@Echo Off
Set PassLenght=12
 
If Not "%1"=="" Set PassLenght=%1
SetLocal EnableDelayedExpansion EnableExtensions
Set TotalChars=65
Set CharSet=0123456789$#_abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWQYZ
:Loop
Set /A Rnd=%TotalChars%*%Random%/32768
Set Pswd=!CharSet:~%Rnd%,1!%Pswd%
Set /A PassLenght-=1
If %PassLenght% GTR 0 GoTo Loop
Echo %Pswd%
Pause>Nul

@ECHO OFF
COLOR 0A
 
:: получаем длину пароля в цифрах
set length_pass=35
 
:: тип используемых символов в пароле
::  использование группы - yes/no
set use_symbol_en_small=yes
set use_symbol_en_big=yes
set use_symbol_ru_small=no
set use_symbol_ru_big=no
set use_symbol_numbers=yes
set use_symbol_special=no
 
:: -----------------== начало скрипта ==-----------------------
 
:: обнуляем переменные
set number_symbol_in_use=0
 
:: задаём наборы символов групп
set group_en_small=a d c d e f g h i j k l m n o p q r s t u v w x y z
set group_en_big=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
set group_ru_small=а б в г д е ё ж з и й к л м н о п р с т у ф х ц ч ш щ ъ ы ь э ю я
set group_ru_big=А Б В Г Д Е Ё Ж З И Й К Л М Н О П Р С Т У Ф Х Ц Ч Ш Щ Ъ Ы Ь Э Ю Я
set group_numbers=0 1 2 3 4 5 6 7 8 9
set group_special=~ ` @ # $ № : { } / \ + - _ . '
 
:: узнаём кол-во символов которые будут использоваться и составляем строку выбора
if %use_symbol_en_small%==yes (
    set /a number_symbol_in_use=%number_symbol_in_use%+26
    set symbol_in_use=%group_en_small%
)
if %use_symbol_en_big%==yes (
    set /a number_symbol_in_use=%number_symbol_in_use%+26
    set symbol_in_use=%symbol_in_use% %group_en_big%
)
if %use_symbol_ru_small%==yes (
    set /a number_symbol_in_use=%number_symbol_in_use%+33
    set symbol_in_use=%symbol_in_use% %group_ru_small%
)
if %use_symbol_ru_big%==yes (
    set /a number_symbol_in_use=%number_symbol_in_use%+33
    set symbol_in_use=%symbol_in_use% %group_ru_big%
)
if %use_symbol_numbers%==yes (
    set /a number_symbol_in_use=%number_symbol_in_use%+10
    set symbol_in_use=%symbol_in_use% %group_numbers%
)
if %use_symbol_special%==yes (
    set /a number_symbol_in_use=%number_symbol_in_use%+16
    set symbol_in_use=%symbol_in_use% %group_special%
)
 
:: вычисляем интервал принадлежащий одному символу
set /a symbol_step_random=32767/%number_symbol_in_use%
 
:: запускаем цикл с шагом 1 и длиной в кол-во символов в пароле с передачей рандомного числа
for /l %%a in (1,1,%length_pass%) do call :randominaze %RANDOM%
 
echo Random password  -  %passkey%
 
pause>nul
 
exit /b 0
 
:randominaze
 
set randomnumber=%RANDOM%
set cycle_number=0
set previous_number_letter=0
for %%b in (%symbol_in_use%) do call :division %%b
exit /b 0
 
:division
set letter=%1
set /a cycle_number=%cycle_number%+1
set /a number_letter=%symbol_step_random%*%cycle_number%
if /i %randomnumber% LEQ %number_letter% (
    if /i %randomnumber% GTR %previous_number_letter% (
        set passkey=%passkey%%letter%
    )
)
set previous_number_letter=%number_letter%
exit /b 0

@echo off
SetLocal EnableExtensions
 
Call :GetSystemVersion "OSVer" "Core" "Build"
Echo Your operating system: %OSVer% %Core% %Build%
 
pause
goto :eof
 
:GetSystemVersion
:: Определить версию ОС
:: %1-исх.Переменная для хранения названия ОС
:: %2-исх.Переменная для хранения разрядности ОС
:: %3-исх.Переменная для хранения версии сборки ОС
  Set "Bitness=x64"& If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set "Bitness=x32"
  set "%~2=%Bitness%"
  For /F "delims=" %%a in ('ver') do set _ver=%%a
  Set _ver="%_ver: =" "%"
  For %%a in (%_ver%) do set _ver=%%~a
  for /F "delims=]" %%a in ("%_ver%") do set %~3=%%a
  set _ver=%_ver:~0,3%
  SET %~1=Unknown
  if "%_ver%"=="5.0" SET %~1=Windows 2000
  if "%_ver%"=="5.1" SET %~1=Windows XP
  if "%_ver%"=="5.2" if "%Bitness%"=="x64" (SET %~1=Windows XP) else (SET %~1=Windows 2003)
  if "%_ver%"=="6.0" (
    Reg.exe query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "ProductName"|>nul Find /i "Vista"&&(
    SET %~1=Windows Vista) || (SET %~1=Windows 2008)
  )
  if "%_ver%"=="6.1" SET %~1=Windows 7
  if "%_ver%"=="6.2" SET %~1=Windows 8
  if "%_ver%"=="6.3" SET %~1=Windows 8.1
  if "%_ver%"=="6.4" SET %~1=Windows 10
  if "%_ver%"=="10." SET %~1=Windows 10
  set _ver=
Exit /B

@echo off
SetLocal EnableExtensions
 
call :GetSystemVersion "OSVer" "Core" "Build" "Family" "EnvironCore"
 
echo Версия ОС:      %OSVer%
echo Рязрядность ОС: %Core%
echo Сборка:         %Build%
echo Семейство:      %Family%
echo Разрядность среды запуска Batch: %EnvironCore%
 
pause
Exit /B
 
:GetSystemVersion [OSVersion] [OSCore] [OSBuild] [OSFamily] [EnvironmentCore]
:: Определить версию ОС
:: %1-исх.Переменная для хранения названия ОС
:: %2-исх.Переменная для хранения разрядности ОС
:: %3-исх.Переменная для хранения версии сборки ОС
:: %4-исх.Переменная, идентифицирующая семейство ОС (9x, NT, Vista)
:: %5-исх.Переменная, идентифицирующая разрядность среды, из-под которой запущен скрипт
  Set "xOS=x64"& If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set "xOS=x32"
  set "%~2=%xOS%"
  set "%~5=x32"& if "%xOS%"=="x64" echo "%PROGRAMFILES%" |>nul find "x86" || set "%~5=x64"
  set "_key=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"
  For /f "tokens=2*" %%a In ('Reg.exe query "%_key%" /v "CurrentBuildNumber"^|Find "CurrentBuildNumber"') do set "%~3=%%~b"
  For /f "tokens=2*" %%a In ('Reg.exe query "%_key%" /v "CurrentVersion"^|Find "CurrentVersion"') do set "_ver=%%~b"
  For /f "tokens=2*" %%a In ('Reg.exe query "%_key%" /v "ProductName"^|Find "ProductName"') do set "%~1=%%~b"
  if "%_ver:~0,1%"=="6" (set "%~4=Vista") else (set "%~4=NT")
Exit /B